DigiPara Liftdesigner LDX API
Loading...
Searching...
No Matches
Flags

API method: ILDXFloorLevel5.FLOOR_LEVEL_MODE

Treename: FLL.

2 code examples follow.

Example 1: Special floor level flags

 ' from Samples/Src/LDXAPIExamples/Example_LDXFloorLevel.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "FLL.", "LDXFloorLevel~FLOOR_LEVEL_MODE", "Special floor level flags")>
 Public Shared Sub SetSpecialFloorFlags(ByRef ldxDocument As DigiPara.LDX.LDXDocument)

     Dim fll = ldxDocument.FloorLevels

     While fll.Count < 6
         Dim index = fll.Count
         fll.InsertAt(index).DESC = index.ToString()
     End While

     ' mark lowest floor as such
     With fll.Item(0)
         .FLOOR_LEVEL_MODE = .FLOOR_LEVEL_MODE Or DigiPara.LDX.FloorLevelModes.flmBK1BottomLevel Or DigiPara.LDX.FloorLevelModes.flmBK2BottomLevel
     End With

     ' mark top floor as such
     With fll.Item(fll.Count - 1)
         .FLOOR_LEVEL_MODE = .FLOOR_LEVEL_MODE Or DigiPara.LDX.FloorLevelModes.flmBK1TopLevel Or DigiPara.LDX.FloorLevelModes.flmBK2TopLevel
     End With

     ' mark first floor as main entrance
     With fll.Item(1)
         .FLOOR_LEVEL_MODE = .FLOOR_LEVEL_MODE Or DigiPara.LDX.FloorLevelModes.flmEntranceLevel
     End With

     ' mark second floor as evacuation floor
     With fll.Item(2)
         .FLOOR_LEVEL_MODE = .FLOOR_LEVEL_MODE Or DigiPara.LDX.FloorLevelModes.flmBK1EvacuationLevel Or DigiPara.LDX.FloorLevelModes.flmBK2EvacuationLevel
     End With

     ' mark third floor as controller floor
     With fll.Item(3)
         .FLOOR_LEVEL_MODE = .FLOOR_LEVEL_MODE Or DigiPara.LDX.FloorLevelModes.flmBK1ControllerLevel Or DigiPara.LDX.FloorLevelModes.flmBK2ControllerLevel
     End With

     ' mark fourth floor as two kinds of user defined special
     With fll.Item(4)
         .FLOOR_LEVEL_MODE = .FLOOR_LEVEL_MODE Or DigiPara.LDX.FloorLevelModes.flmBK1UserType1Level Or DigiPara.LDX.FloorLevelModes.flmUserType2Level
     End With

     System.Windows.Forms.MessageBox.Show("Go to Project Ribbon, Group and Shaft Configurator, Floor Types to view result", "Floor Levels")

 End Sub

Example 2: Activate / deactivate Standard floor level

 ' from Samples/Src/LDXAPIExamples/Example_LDXFloorLevels.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "FLL.", "LDXFloorLevel~FLOOR_LEVEL_MODE", "Activate / deactivate Standard floor level")>
    Public Shared Sub AddRemoveFloorLevelSegments(ByRef ldxDocument As DigiPara.LDX.LDXDocument)

        If ldxDocument.GetLDXObject("FLL.") Is Nothing Then
            MsgBox("Desired floor list not found!")
            Exit Sub
        End If


        With DirectCast(ldxDocument.GetLDXObject("FLL.").LDXType, DigiPara.LDX.LDXFloorLevels)
            If .StandardFloorLevel.FLOOR_LEVEL_MODE And DigiPara.LDX.FloorLevelModes.flmCreateFloor Then
                .StandardFloorLevel.FLOOR_LEVEL_MODE = .StandardFloorLevel.FLOOR_LEVEL_MODE And Not DigiPara.LDX.FloorLevelModes.flmCreateFloor
            Else
                .StandardFloorLevel.FLOOR_LEVEL_MODE = .StandardFloorLevel.FLOOR_LEVEL_MODE Or DigiPara.LDX.FloorLevelModes.flmCreateFloor
            End If

        End With

    End Sub