DigiPara Liftdesigner LDX API
Loading...
Searching...
No Matches
Change custom hole properties

API method: ILDXHole5.X1

Treename: Shaft0.Hole1.

 ' from Samples/Src/LDXAPIExamples/Example_LDXShaft.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.Hole1.", "LDXHole~X1", "Change custom hole properties")>
 Public Shared Sub ChangeCustomHoleProperties(ldxDocument As DigiPara.LDX.LDXDocument)

     Dim ldxHole As DigiPara.LDX.LDXHole = ldxDocument.Shafts(0).Comp.Holes(1)
     If ldxHole Is Nothing Then
         MsgBox("Desired hole not found!")
         Exit Sub
     End If

     With ldxHole
         If (.HoleMode And DigiPara.LDX.HoleModes.hmCylinder) = DigiPara.LDX.HoleModes.hmCylinder Then

             ' make rectangular
             .HoleMode = .HoleMode And Not DigiPara.LDX.HoleModes.hmCylinder

             ' Show X and Y dimensions
             .HoleMode = .HoleMode Or DigiPara.LDX.HoleModes.hmDimX Or DigiPara.LDX.HoleModes.hmDimZ

             ' Automatically calculate X0 and Y0
             .Object.SetValue("Me.DistMode.Z1", Convert.ToInt32(.Object.GetValue("Me.DistMode.Z1")) And Not DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmCalcAuto)
             .Object.SetValue("Me.DistMode.X1", Convert.ToInt32(.Object.GetValue("Me.DistMode.X1")) And Not DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmCalcAuto)
             .Object.SetValue("Me.DistMode.DZ", Convert.ToInt32(.Object.GetValue("Me.DistMode.DZ")) And Not DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmCalcAuto)
             .Object.SetValue("Me.DistMode.DX", Convert.ToInt32(.Object.GetValue("Me.DistMode.DX")) And Not DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmCalcAuto)
             .Object.SetValue("Me.DistMode.Z0", Convert.ToInt32(.Object.GetValue("Me.DistMode.Z0")) Or DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmCalcAuto)
             .Object.SetValue("Me.DistMode.X0", Convert.ToInt32(.Object.GetValue("Me.DistMode.X0")) Or DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmCalcAuto)

             ' Set coordinate system to shaft wall
             .PrimaryAxisMode = DigiPara.LDX.MixedAxisModes.mamY Or DigiPara.LDX.MixedAxisModes.mamSourceWall
             .SecondaryAxisMode = DigiPara.LDX.MixedAxisModes.mamZ Or DigiPara.LDX.MixedAxisModes.mamSourceWall
             .TertiaryAxisMode = DigiPara.LDX.MixedAxisModes.mamX Or DigiPara.LDX.MixedAxisModes.mamSourceWall

             ' Change hole's distance from left shaft wall when viewed from rear
             .X1 = 500
             ' Change hole's distance from shaft top when viewed from rear
             .Z1 = 3000
         Else

             ' make cylinder
             .HoleMode = .HoleMode Or DigiPara.LDX.HoleModes.hmCylinder


             ' Hide X and Y dimensions
             .HoleMode = .HoleMode And Not (DigiPara.LDX.HoleModes.hmDimX Or DigiPara.LDX.HoleModes.hmDimZ)

             ' Change hole's distance from left shaft wall when viewed from rear
             .X1 = 100
             ' Change hole's distance from shaft top when viewed from rear
             .Z1 = 2000
         End If

     End With
 End Sub