DigiPara Liftdesigner LDX API
Loading...
Searching...
No Matches
Load CAD File into project

API method: ILDXInsertedCADFile5.CADF_LOADED_FILE

Treename: Shaft0.CAD File.

 ' from Samples/Src/LDXAPIExamples/Example_LDXInsertedCADFile.vb

 Private Shared Function FetchOrLoadCADFile(comp As DigiPara.LDX.LDXComp) As DigiPara.LDX.LDXInsertedCADFile
     ' find user component
     Dim userComAsObj As DigiPara.LDX.LDXObject = comp.Object.GetObjectByRelativeName("CAD File.")
     If userComAsObj Is Nothing Then
         ' add user component
         userComAsObj = comp.UserChildren.Add("CAD File")
     End If
     ' cast to correct type
     Dim userComp As DigiPara.LDX.LDXUserComp = DirectCast(userComAsObj.LDXType, DigiPara.LDX.LDXUserComp)
     ' set mode: use full equations
     userComp.Mode = DigiPara.LDX.UserCompModes.ucmUseEquationsAndAngle
     'userComp.Mode = DigiPara.LDX.UserCompModes.ucmUsePositionAndAngle
     ' create CAD file
     Dim cadFile As DigiPara.LDX.LDXInsertedCADFile = userComp.CreateInsertedCADFile()
     ' assign CAD file (simple sample file from pool)
     cadFile.CADF_LOADED_FILE = comp.Object.Document.Application.PoolPath() + "Assets\\0\\coordinatesystem.ipt"
     ' move up
     userComp.SetEquation(DigiPara.LDX.ProfileEquationType.peqtLocalPositionX, "1000")
     userComp.SetEquation(DigiPara.LDX.ProfileEquationType.peqtLocalPositionY, "1000")
     userComp.SetEquation(DigiPara.LDX.ProfileEquationType.peqtLocalPositionZ, "12000")
     'with the flag DigiPara.LDX.UserCompModes.ucmUsePositionAndAngle instead of DigiPara.LDX.UserCompModes.ucmUseEquationsAndAngle set, you'd position using
     'userComp.Object.SetValue("X0", 1000)
     'userComp.Object.SetValue("Y0", 1000)
     'userComp.Object.SetValue("Z0", 12000)

     ' only user comps with RID > 0 are treated as fully valid in property grid
     userComp.UserCompTab.Object.SetValue("USERC_RID", 1)

     Return cadFile
 End Function

 <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.CAD File.", "LDXInsertedCADFile~CADF_LOADED_FILE", "Load CAD File into project")>
 Public Shared Sub LoadCAD(ByRef ldxDocument As DigiPara.LDX.LDXDocument)

     If ldxDocument.GetLDXObject("Shaft0.") Is Nothing Then
         MsgBox("Required object not found!")
         Exit Sub
     End If

     FetchOrLoadCADFile(ldxDocument.GetLDXObject("Shaft0.").Comp)
 End Sub