DigiPara Liftdesigner LDX API
Loading...
Searching...
No Matches
Change separator beam properties

API method: ILDXSeparatorBeam5.COMP_DIST

Treename: Shaft0.CW.BracketList.Bracket7.SepBeam.

2 code examples follow.

Example 1: Change separator beam properties

 ' from Samples/Src/LDXAPIExamples/Example_LDXRailBracket.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.CW.BracketList.Bracket7.SepBeam.", "LDXSeparatorBeam~COMP_DIST", "Change separator beam properties")>
 Public Shared Sub ChangeSeparatorBeamProperties(ldxDocument As DigiPara.LDX.LDXDocument)

     If ldxDocument.GetLDXObject("Shaft0.CW.BracketList.Bracket7.SepBeam.") Is Nothing Then
         MsgBox("Separator beam in desired rail bracket not found! Please reload the relevant .ld3 file.")
         Exit Sub
     End If

     ' enable separator beams so they do not vanish on the next recalc
     With DirectCast(ldxDocument.GetLDXObject("Shaft0.CW.BracketList.").LDXType, DigiPara.LDX.LDXRailBrackets)
         .RBL_MODE = .RBL_MODE Or DigiPara.LDX.RailBracketsModes.rbmSeparatorBeam
     End With

     With DirectCast(ldxDocument.GetLDXObject("Shaft0.CW.BracketList.Bracket7.SepBeam.").LDXType, DigiPara.LDX.LDXSeparatorBeam)
         ' Activate beam
         .Object.Active = True
         ' Distnace from the 
         .COMP_DIST = 333
         ' Beam Clearance from the left
         .SeparatorBeamTab.SetValue("SEPB_CLR_LEFT", 555)
         ' Beam clearance from the right
         .SeparatorBeamTab.SetValue("SEPB_CLR_RIGHT", 666)
         .Object.SendChangeNotification("", "")
     End With

 End Sub

Example 2: Disable single separator beam

 ' from Samples/Src/LDXAPIExamples/Example_LDXRailBracket.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.CW.BracketList.Bracket7.SepBeam.", "LDXSeparatorBeam~COMP_DIST", "Disable single separator beam")>
 Public Shared Sub DisableSingleSeparatorBeam(ldxDocument As DigiPara.LDX.LDXDocument)

     If ldxDocument.GetLDXObject("Shaft0.CW.BracketList.Bracket7.SepBeam.") Is Nothing Then
         MsgBox("Separator beam in desired rail bracket not found! Please reload the relevant .ld3 file.")
         Exit Sub
     End If

     With DirectCast(ldxDocument.GetLDXObject("Shaft0.CW.BracketList.").LDXType, DigiPara.LDX.LDXRailBrackets)
         ' enable separator beams so they do not vanish on the next recalc
         .RBL_MODE = .RBL_MODE Or DigiPara.LDX.RailBracketsModes.rbmSeparatorBeam
         ' do the recalc to make sure they are all activated
         .Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
     End With

     With DirectCast(ldxDocument.GetLDXObject("Shaft0.CW.BracketList.Bracket7.").LDXType, DigiPara.LDX.LDXRailBracket)
         ' allow individual anchor rails and separator beams on this bracket (new in 18.0)
         .RailBracketModes = .RailBracketModes Or DigiPara.LDX.RailBracketModes.rbmUserdefinedFixing
     End With

     With DirectCast(ldxDocument.GetLDXObject("Shaft0.CW.BracketList.Bracket7.SepBeam.").LDXType, DigiPara.LDX.LDXSeparatorBeam)
         ' Deactivate beam via geometry options
         .Comp.CADSettings = (.Comp.CADSettings And Not DigiPara.LDX.CompCADSettings.csUserOn) Or DigiPara.LDX.CompCADSettings.csUserOff

         ' this would work here, too (not with 17.0)
         '.Object.Active = False

         ' not strictly required in this case, no action will be taken (again, not in 17.0)
         .Object.SendChangeNotification("", "")
     End With
 End Sub