DigiPara Liftdesigner LDX API
Loading...
Searching...
No Matches
Add new elevator

API method: ILDXShafts.BANK_2_START_SX

 ' from Samples/Src/LDXAPIExamples/Example_GroupsConfiguration.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "", "LDXShafts~BANK_2_START_SX", "Add new elevator")>
    Public Shared Sub AddNewElevator(ByRef ldxDocument As DigiPara.LDX.LDXDocument)

        Dim sw As Integer() = New Integer(12) {}

        ' Hydraulic type if hydraulic elevator is set (set sw(10) also!)
        ' 0 = 1 piston, assembly set 1:1
        ' 1 = 1 piston, assembly set 2:1
        ' 2 = 1 piston, central piston (SW(6) = 3 !!)
        ' 3 = 2 pistons, 1:1 (SW(6) = 3 !!)
        ' 4 = 2 pistons, 2:1 (SW(6) = 3 !!)
        ' 5 = 2 pistons, central pistons (SW(6) = 3 !!)
        ' Unused for electric / traction elevator
        sw(0) = 0

        ' M/R wall, if M/R is beneath
        ' 0 = M/R not beneath
        ' 1 = front side
        ' 2 = rear side
        ' 3 = left side
        ' 4 = right side
        sw(1) = 0

        ' 1 = M/R down beneath
        ' 2 = M/R above (do not use for hydraulic types)
        ' 3 = M/R top beneath
        sw(2) = 2

        ' CW wall ( do not move the CW at a the same walls as doors) or wall of hydraulic assembly set
        ' 1 = front side
        ' 2 = rear side
        ' 3 = left side
        ' 4 = right side
        sw(3) = DigiPara.LDX.WallType.wtRear

        ' Car rope situation if (traction elevator only)
        ' 10 = 1:1
        ' 11 = 2:1 one pulley (above cabine)
        ' 12 = 2:1 two pulleys (above cabine)
        ' 13 = 2:1 two pulleys (below cabine)   
        sw(4) = 10

        ' CW rope situation if (traction elevator)
        ' 10 = 1:1
        ' 11 = 2:1 one pulley
        ' 12 = 2:1 two pulleys            
        sw(5) = 10

        ' CW wall ( do not move the CW at a the same walls as doors) or wall of hydraulic assembly set
        ' 1 = front side
        ' 2 = rear side
        ' 3 = left side
        ' 4 = right side              
        sw(6) = DigiPara.LDX.WallType.wtRear

        ' for future use
        sw(7) = 0
        sw(8) = 0
        sw(9) = 0

        ' Type of elevator
        ' -1 = No elevator (remove shaft) (p11 = ShaftNo !!)
        ' 1 = Traction elevator
        ' 2 = Hydraulic elevator (all types)
        ' 3 = Copy existing elevator (p11 = ShaftNo to copy !!)
        sw(10) = 1

        ' Number of shaft to be removed or copied
        ' 0 = "Shaft0." (p10 = -1 !!)
        ' 1 = "Shaft1."
        ' 2 = "Shaft2.", etc.
        sw(11) = 0

        sw(12) = 0

        ' Create shaft
        ldxDocument.CreateNewShaft(sw(0), sw(1), sw(2), sw(3), sw(4), sw(5), sw(6), sw(7), sw(8), sw(9), sw(10), sw(11), sw(12))
        ' Initialize new shaft from duty tables
        ldxDocument.Shafts.ActiveShaft.InitFromDutyTables64(5201014, DigiPara.LDX.WallType.wtRear, 1, 1, 0, 0)

        ' Move the new shaft to Bank 1, right side
        ldxDocument.Shafts.MoveShaft(ldxDocument.Shafts.ActiveShaft.Comp.SX, ldxDocument.Shafts.BANK_2_START_SX)
        ldxDocument.Shafts.BANK_2_START_SX = ldxDocument.Shafts.BANK_2_START_SX + 1

        ' Add front entriy in 1st floor of new shaft
        ldxDocument.FloorLevels(0).SetService(ldxDocument.Shafts.ActiveShaft.Comp.SX, 1)

    End Sub