|
DigiPara Liftdesigner LDX API
|
API method: ILDXSheetFrame5.CreateDynDim
Treename: Shaft0.
' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrameOverwrites.vb
<APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.", "LDXSheetFrame~CreateDynDim", "Create dynamic dimensions")>
Public Shared Sub CreateDynamicDimension(ByRef ldxDocument As DigiPara.LDX.LDXDocument)
Dim ldxSheetFrame As DigiPara.LDX.LDXSheetFrame = ldxDocument.Sheets.ActiveSheet.ActiveSheetFrame
If ldxSheetFrame?.ViewType And DigiPara.LDX.SheetFrameViewType.shfvtOrthogonal = 0 Then
MsgBox("Please activate an orthogonal view!")
Exit Sub
End If
Dim ldxSheetFrameOverwrites = ldxSheetFrame.SheetFrameOverwrites
If ldxSheetFrameOverwrites.CountByType(DigiPara.LDX.SheetFrameOverwriteType.sfoDynDim) = 0 Then
' remove regular dimension overwrites
ldxSheetFrameOverwrites.DeleteType(DigiPara.LDX.SheetFrameOverwriteType.sfoDim)
' create new dimensions
Dim PGP_CODE_basepoint = 9000
Dim PGP_CODE_shaft_outer_left_front_below = 9008
Dim ldxShaftObject As DigiPara.LDX.LDXObject = ldxDocument.Shaft.Object
Dim ldxCarObject = ldxDocument.Shaft.Car.Object
' The LDXSheetFrame.CreateDynDimEx method creates a simple dynamic dimension overwrite in one step. It
' takes the direction, the two objects to connect, and the PGP_CODE_NOs of the dynamic dimension points to use.
Dim ldxDynDimOverwriteAligned As DigiPara.LDX.LDXSheetFrameOverwrite =
ldxSheetFrame.CreateDynDimEx(DigiPara.LDX.DynDimMode.ddmAligned, ldxShaftObject, PGP_CODE_shaft_outer_left_front_below, ldxCarObject, PGP_CODE_basepoint)
Dim ldxDynDimOverwriteHorizontal As DigiPara.LDX.LDXSheetFrameOverwrite =
ldxSheetFrame.CreateDynDimEx(DigiPara.LDX.DynDimMode.ddmHorizontal, ldxShaftObject, PGP_CODE_shaft_outer_left_front_below, ldxCarObject, PGP_CODE_basepoint)
Dim ldxDynDimOverwriteVertical As DigiPara.LDX.LDXSheetFrameOverwrite =
ldxSheetFrame.CreateDynDimEx(DigiPara.LDX.DynDimMode.ddmVertical, ldxShaftObject, PGP_CODE_shaft_outer_left_front_below, ldxCarObject, PGP_CODE_basepoint)
' move the aligned dimension a bit with another overwrite; the dynamic dimensions are created under the first of the
' two connected objects, the DynDims. subobject, with the name that can be retrieved from the overwrite.
Dim ldxDimOverwrite As DigiPara.LDX.LDXSheetFrameOverwrite = ldxSheetFrameOverwrites.Add(ldxShaftObject.TreeName & "DynDims." & ldxDynDimOverwriteAligned.Name, DigiPara.LDX.SheetFrameOverwriteType.sfoDim)
ldxDimOverwrite.Point.Y = -400
' and give it long extension lines
ldxDimOverwrite.DimMode = (ldxDimOverwrite.DimMode And Not DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmDefaultLineMask) Or DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmLine1 Or DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmLine2
' modify the dimension end point of the horizontal dimension with rules so it goes to the upper corner of the car
ldxDynDimOverwriteHorizontal.SetRule(DigiPara.LDX.DynDimPoint.ddp1, DigiPara.LDX.DynDimRuleType.ddrZ0, "LD(""Me.HEIGHT"")")
ldxDynDimOverwriteHorizontal.SetRule(DigiPara.LDX.DynDimPoint.ddp1, DigiPara.LDX.DynDimRuleType.ddrY0, "LD(""Me.CD"")*.5")
ldxDynDimOverwriteHorizontal.SetRule(DigiPara.LDX.DynDimPoint.ddp1, DigiPara.LDX.DynDimRuleType.ddrX0, "LD(""Me.CW"")*.5")
' make all regular dimensions invisible
ldxSheetFrameOverwrites.Add("*", DigiPara.LDX.SheetFrameOverwriteType.sfoDim).DimMode = DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmDisabled
' make only our dynamic dimensions visible
ldxSheetFrameOverwrites.Add(ldxShaftObject.TreeName & "DynDims.*", DigiPara.LDX.SheetFrameOverwriteType.sfoDim).DimMode = DigiPara.LDX.SheetFrameOverwriteDimModes.sfodmNone
Else
' clean up everything
ldxSheetFrameOverwrites.DeleteType(DigiPara.LDX.SheetFrameOverwriteType.sfoDynDim)
ldxSheetFrameOverwrites.DeleteType(DigiPara.LDX.SheetFrameOverwriteType.sfoDim)
End If
End Sub