|
DigiPara Liftdesigner LDX API
|
API method: ILDXSheetFrame5.IncludeClasses
Treename: Sheets.LdvSheet1.
2 code examples follow.
' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrame.vb
Shared IncludeClasses_Run As Integer = 0
<APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Sheets.LdvSheet1.", "LDXSheetFrame~IncludeClasses", "Class based filtering (old style)")>
Public Shared Sub IncludeClasses(ByRef ldxDocument As DigiPara.LDX.LDXDocument)
' Note: Do not use the .ExcludeClasses/.IncludeClasses mechanism
' if you use the new .ClassFilters mechanism, too. Setting .Include/.ExcludeClasses
' is implemented in terms of .ClassFilters; for a complicated .ClassFilters setup,
' setting .Include/.ExcludeClasses may destroy it. And reading .Include/.ExcludeClasses
' is only going to give you partial information.
If ldxDocument.GetObject("Sheets.LdvSheet1.LdvFrame3.") Is Nothing Then
MsgBox("Desired sheet frames not found! Please reload the relevant .ld3 file.")
Exit Sub
End If
IncludeClasses_Run = IncludeClasses_Run + 1
With DirectCast(ldxDocument.GetLDXObject("Sheets.LdvSheet1.LdvFrame3.").LDXType, DigiPara.LDX.LDXSheetFrame)
' disable visibility by category
.VisibleProductGroups = DigiPara.LDX.SheetFrameProductGroups.shfpNone
Select Case IncludeClasses_Run
Case 1
' make only the car visible
.ExcludeClasses = ""
.IncludeClasses = "LDXCar"
Case 2
' car and frame visible
.ExcludeClasses = ""
.IncludeClasses = "LDXCar,LDXCarFrame"
Case 3
' include statements win over exclude statements (for human readibility, whitespace after the comma is fine)
.ExcludeClasses = "LDXCar, LDXCarFrame"
.IncludeClasses = "LDXCarFrame"
Case 4
' exclude statements win over VisibleProductGroups
.ExcludeClasses = "LDXCar, LDXCarFrame, LDXLandingDoor"
.IncludeClasses = ""
.VisibleProductGroups = DigiPara.LDX.SheetFrameProductGroups.shfpCarAndDoors
Case Else
' back to normal
.ExcludeClasses = ""
.IncludeClasses = ""
.VisibleProductGroups = DigiPara.LDX.SheetFrameProductGroups.shfpShaft Or DigiPara.LDX.SheetFrameProductGroups.shfpCarAndDoors
IncludeClasses_Run = 0
End Select
End With
End Sub
' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrame.vb
Shared ClassFilters_Run As Integer = 0
<APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Sheets.LdvSheet1.", "LDXSheetFrame~IncludeClasses", "Class based filtering")>
Public Shared Sub ClassFilters(ByRef ldxDocument As DigiPara.LDX.LDXDocument)
If ldxDocument.GetObject("Sheets.LdvSheet1.LdvFrame3.") Is Nothing Then
MsgBox("Desired sheet frames not found! Please reload the relevant .ld3 file.")
Exit Sub
End If
Dim VisibleClassesTotal1 As String
Dim VisibleClassesTotal2 As String
Dim VisibleClasses1 As String
Dim VisibleClasses2 As String
ClassFilters_Run = ClassFilters_Run + 1
With DirectCast(ldxDocument.GetLDXObject("Sheets.LdvSheet1.LdvFrame3.").LDXType, DigiPara.LDX.LDXSheetFrame)
' some default values: Always make car, car frame and shaft visible (unless overwritten by the specific sub-demo)
.VisibleProductGroups = DigiPara.LDX.SheetFrameProductGroups.shfpShaft Or DigiPara.LDX.SheetFrameProductGroups.shfpCarAndDoors Or DigiPara.LDX.SheetFrameProductGroups.shfpCarFrame
If .FrameMode2 And DigiPara.LDX.SheetFrameModes2.shfrm2SymbolicVertical = DigiPara.LDX.SheetFrameModes2.shfrm2SymbolicVertical Then
' only try to set these once
.SheetFrameOverwrites.Clear()
.FrameMode2 = .FrameMode2 And Not DigiPara.LDX.SheetFrameModes2.shfrm2SymbolicVertical
.Scale = 1.0 / 100
End If
' all classes availale in the document
VisibleClassesTotal1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmIncludeAll)
VisibleClassesTotal2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmIncludeAll)
' .ClassFilters are processed in order, first from the sheet frame, then the sheet,
' then the sheets. The first match wins and the arithmetic sign in front of the filter
' determines whether an object is shown or not. + shows it, - hides it.
Select Case ClassFilters_Run
Case 1
' make the car invisible
.ClassFilters = "-LDXCar"
' mark dirtry (so that .GetVisibleClasses returns up to date information)
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
' retrieve the actually visible classes from the sheet frame, verify that the car is not in it
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCar,"))
Case 2
' the list is comma separated, whitespace AFTER the comma optional (no whitespace before it)
' car and frame invisible
.ClassFilters = "-LDXCar, -LDXCarFrame"
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCarFrame,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCarFrame,"))
Case 3
' the first match wins; this leaves the car frame visible.
.ClassFilters = "+LDXCarFrame, -LDXCar, -LDXCarFrame"
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCar,"))
System.Diagnostics.Debug.Assert(VisibleClasses1.Contains("+LDXCarFrame,"))
System.Diagnostics.Debug.Assert(VisibleClasses2.Contains("+LDXCar/LDXCarFrame,"))
Case 4
' a lone + or - matches all objects. So by sticking a - at the end, you can hide all but the explicitly enabled.
' (it does not make sense to put a lone + or - into the middle of the filters, the rest of the filter would get ignored)
' this shows only the car
.ClassFilters = "+LDXCar, -"
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault)
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault)
System.Diagnostics.Debug.Assert(VisibleClasses1 = "+LDXCar")
System.Diagnostics.Debug.Assert(VisibleClasses2 = "+LDXShaft/LDXCar")
Case 5
' Filters can reference base classes. Both LDXShaftDoor and LDXLandingDoor are also LDXDoor.
' All visible components themselves are LDXComp, all intermediate tree objects are LDXObject.
' this shows only doors (all kinds)
.ClassFilters = "+LDXDoor, -"
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCar,"))
System.Diagnostics.Debug.Assert(VisibleClasses1.Contains("LDXCarDoor,"))
System.Diagnostics.Debug.Assert(VisibleClasses1.Contains("LDXLandingDoor,"))
Case 6
' Again, the first filter matches. So by first specifying a special class, then the base class, you can
' specify exceptions.
' this shows only doors that are not car doors
.ClassFilters = "-LDXCarDoor, +LDXDoor, -"
' of course, here this would be equivalent to just
'.ClassFilters = "+LDXLandingDoor, -"
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCarDoor,"))
System.Diagnostics.Debug.Assert(VisibleClasses1.Contains("LDXLandingDoor,"))
Case 7
' You can also filter by the parent type using the / separator. First comes the parent, then the child.
' this shows only doors that are children of cars
.ClassFilters = "+LDXCar/LDXDoor, -"
' equivalent to
'.ClassFilters = "+LDXCarDoor, -"
' this is mostly useful for more generic classes that can be found everywhere, like LDXHole or LDXUserComp.
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault) + ","
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXLandingDoor,"))
System.Diagnostics.Debug.Assert(VisibleClasses1.Contains("LDXCarDoor,"))
Case 8
' Arbitrary long chains are supported, though they rarely make sense.
' this shows only doors that are granddrandchildren of the shaft
.ClassFilters = "+LDXShaft/LDXObject/LDXObject/LDXDoor, -"
' equivalent to
'.ClassFilters = "+LDXLandingDoor, -"
' because they would match the more precise pattern LDXShaft/LDXEntries/LDXEntry/LDXLandingDoor.
' this is mostly useful for more generic classes that can be found everywhere, like LDXHole.
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault)
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDefault)
System.Diagnostics.Debug.Assert(VisibleClasses1 = "+LDXLandingDoor")
System.Diagnostics.Debug.Assert(VisibleClasses2 = "+LDXEntry/LDXLandingDoor")
Case 9
' class filters win over VisibleProductGroups both for excludes and includes
' here we enable the car frame, disable the car and landing doors and enable the shaft and its hole
.ClassFilters = "-LDXCar, +LDXCarFrame, -LDXLandingDoor, +LDXShaft, +LDXShaft/LDXHole, -LDXHole"
.VisibleProductGroups = DigiPara.LDX.SheetFrameProductGroups.shfpCarAndDoors
.Comp.CalculateModel(DigiPara.LDX.CompCalculateModelModes.crvmNone)
' different query mode; the default does not catch the LDXHole
VisibleClasses1 = .GetVisibleClasses(1, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDesignMode)
VisibleClasses2 = .GetVisibleClasses(2, DigiPara.LDX.SheetFrameVisibleClassesModes.sfvcmDesignMode)
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXCar,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses1.Contains("LDXLandingDoor,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("/LDXLandingDoor,"))
System.Diagnostics.Debug.Assert(VisibleClasses1.Contains("LDXCarFrame,"))
System.Diagnostics.Debug.Assert(VisibleClasses2.Contains("+LDXCar/LDXCarFrame,"))
System.Diagnostics.Debug.Assert(VisibleClasses1.Contains("+LDXShaft,"))
System.Diagnostics.Debug.Assert(VisibleClasses2.Contains("+LDXShaft/LDXHole,"))
System.Diagnostics.Debug.Assert(Not VisibleClasses2.Contains("+LDXDuctHole/LDXHole,"))
Case Else
' back to normal
.ClassFilters = ""
ClassFilters_Run = 0
End Select
End With
End Sub