DigiPara Liftdesigner LDX API
Loading...
Searching...
No Matches
Move Shaftdepth Dimension Chain Left Right

API method: ILDXSheetFrameOverwrite5.Id

Treename: Shaft0.Car.CW

2 code examples follow.

Example 1: Move Shaftdepth Dimension Chain Left Right

 ' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrameOverwrites.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.Car.CW", "LDXSheetFrameOverwrite~Id", "Move Shaftdepth Dimension Chain Left Right")>
 Public Shared Sub MoveShaftDepthDimensionChainLeftRight(ByRef ldxDocument As DigiPara.LDX.LDXDocument)


     Dim ldxSheetFrameOverwrites As DigiPara.LDX.LDXSheetFrameOverwrites = ldxDocument.Sheets.ActiveSheet.ActiveSheetFrame.SheetFrameOverwrites
     Dim ldxSheetFrameOverwrite As DigiPara.LDX.LDXSheetFrameOverwrite

     If ldxDocument.Sheets.ActiveSheet.ActiveSheetFrame.ViewType <> DigiPara.LDX.SheetFrameViewType.shfvtPlan Then
         MsgBox("Please activate a PLAN view with a shaft depth dimension!")
         Exit Sub
     End If


     ' 30000 is the Dimension Chain Id
     ldxSheetFrameOverwrite = ldxSheetFrameOverwrites.Add("30000", DigiPara.LDX.SheetFrameOverwriteType.sfoDimChain)

     Dim dimChainMode As DigiPara.LDX.SheetFrameOverwriteDimChainModes
     dimChainMode = ldxSheetFrameOverwrite.DimChainModeVertical

     ' This mode used to be accessible only over .Id. The one for horizontal dimensions was in .Value.

     If dimChainMode = DigiPara.LDX.SheetFrameOverwriteDimChainModes.sfodcmLeft Then
         ' if it is left, move it to the right side
         dimChainMode = DigiPara.LDX.SheetFrameOverwriteDimChainModes.sfodcmRight
     Else
         ' if it is right, move it to the left side
         dimChainMode = DigiPara.LDX.SheetFrameOverwriteDimChainModes.sfodcmLeft
     End If

     ' Apply the value
     ldxSheetFrameOverwrite.DimChainModeVertical = dimChainMode

 End Sub

Example 2: Move CTW DBG Dimension Based on CWT Location

 ' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrameOverwrites.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.CW.BracketList.DBG", "LDXSheetFrameOverwrite~Id", "Move CTW DBG Dimension Based on CWT Location")>
 Public Shared Sub MoveCTWDBGDimensionBasedonCWTLocation(ByRef ldxDocument As DigiPara.LDX.LDXDocument)


     If ldxDocument.Sheets.ActiveSheet.ActiveSheetFrame.ViewType <> DigiPara.LDX.SheetFrameViewType.shfvtPlan Then
         MsgBox("Please activate a PLAN view with a shaft depth dimension!")
         Exit Sub
     End If

     If ldxDocument.GetLDXObject("Shaft0.CW.BracketList.DBG") Is Nothing Then
         MsgBox("Desired dimension not found! Please reload the relevant .ld3 file!")
         Exit Sub
     End If

     Dim ldxSheetFrame As DigiPara.LDX.LDXSheetFrame = ldxDocument.Sheets.ActiveSheet.ActiveSheetFrame
     Dim dimName As String = "Shaft0.CW.BracketList.DBG"
     Dim ldxSheetFrameOverwrites As DigiPara.LDX.LDXSheetFrameOverwrites = ldxSheetFrame.SheetFrameOverwrites
     Dim ldxSheetFrameOverwrite As DigiPara.LDX.LDXSheetFrameOverwrite = ldxSheetFrameOverwrites.Add(dimName, DigiPara.LDX.SheetFrameOverwriteType.sfoDim)
     ldxSheetFrameOverwrite.Description = "&lt;!&gt;45"

     ' note that the 400 is project units, you might divide this by the scale e.g. 20 to get paper units
     If ldxDocument.Shafts(0).CWConsole.Comp.Wall = DigiPara.LDX.WallType.wtLeft Then
         ldxSheetFrameOverwrite.Point.X = 400
         ldxSheetFrameOverwrite.Point.Y = 0
     ElseIf ldxDocument.Shafts(0).CWConsole.Comp.Wall = DigiPara.LDX.WallType.wtRight Then
         ldxSheetFrameOverwrite.Point.X = -400
         ldxSheetFrameOverwrite.Point.Y = 0
     ElseIf ldxDocument.Shafts(0).CWConsole.Comp.Wall = DigiPara.LDX.WallType.wtRear Then
         ldxSheetFrameOverwrite.Point.X = 0
         ldxSheetFrameOverwrite.Point.Y = -400
     End If
 End Sub