DigiPara Liftdesigner LDX API
Loading...
Searching...
No Matches
Change dimension style wholesale

API method: ILDXSheetFrameOverwrite5.Value

Treename: Shaft0.DEPTH

2 code examples follow.

Example 1: Change entire dimension style

 ' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrameOverwrites.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.DEPTH", "LDXSheetFrameOverwrite~Value", "Change entire dimension style")>
 Public Shared Sub ChangeDimensionStyleCompletely(ByRef ldxDocument As DigiPara.LDX.LDXDocument)

     If ldxDocument.GetLDXObject("Shaft0.DEPTH") Is Nothing Then
         MsgBox("Desired dimension not found! Please reload the relevant .ld3 file!")
         Exit Sub
     End If

     Dim ldxSheetFrameOverwrites As DigiPara.LDX.LDXSheetFrameOverwrites = ldxDocument.Sheets.ActiveSheet.ActiveSheetFrame.SheetFrameOverwrites
     Dim ldxSheetFrameOverwrite As DigiPara.LDX.LDXSheetFrameOverwrite = ldxSheetFrameOverwrites.Find("Shaft0.*", DigiPara.LDX.SheetFrameOverwriteType.sfoDimStyle)
     If ldxSheetFrameOverwrite Is Nothing Then
         ldxSheetFrameOverwrite = ldxSheetFrameOverwrites.Add("Shaft0.*", DigiPara.LDX.SheetFrameOverwriteType.sfoDimStyle)
     End If

     If String.IsNullOrEmpty(ldxSheetFrameOverwrite.PrintModeDimStyle) Then
         ' activate special dim style
         ldxSheetFrameOverwrite.PrintModeDimStyle = "LIFT_NO_EDIT"
     Else
         ' deactivate special dim style
         ldxSheetFrameOverwrite.PrintModeDimStyle = Nothing
     End If

 End Sub

Example 2: Change dimension text background

 ' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrameOverwrites.vb

    <APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Shaft0.DEPTH", "LDXSheetFrameOverwrite~Value", "Change dimension text background")>
 Public Shared Sub ChangeDimensionTextBackground(ByRef ldxDocument As DigiPara.LDX.LDXDocument)

     If ldxDocument.GetLDXObject("Shaft0.DEPTH") Is Nothing Then
         MsgBox("Desired dimension not found! Please reload the relevant .ld3 file!")
         Exit Sub
     End If

     Dim ldxSheetFrameOverwrites As DigiPara.LDX.LDXSheetFrameOverwrites = ldxDocument.Sheets.ActiveSheet.ActiveSheetFrame.SheetFrameOverwrites
     Dim ldxSheetFrameOverwrite As DigiPara.LDX.LDXSheetFrameOverwrite = ldxSheetFrameOverwrites.Add("Shaft0.*", DigiPara.LDX.SheetFrameOverwriteType.sfoDimStyle)

     With ldxSheetFrameOverwrite
         Select Case .DimStyleMode And DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorMask
             Case DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorByStyle
                 ' go to color index mode, set color
                 .DimStyleMode = (.DimStyleMode And Not DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorMask) Or
                     DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorIndex
                 .BackgroundFillColorIndex = 4

             Case DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorIndex
                 ' turn off background color (in case dimstyle has it set, which is not usually the case)
                 .DimStyleMode = (.DimStyleMode And Not DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorMask) Or
                     DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorNone

             Case DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorNone
                 ' use drawing background as background fill (typically an invisible effect)
                 .DimStyleMode = (.DimStyleMode And Not DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorMask) Or
                     DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorBackground

             Case Else
                 ' back to taking the fill color from the DIMSTYLE
                 .DimStyleMode = (.DimStyleMode And Not DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorMask) Or
                     DigiPara.LDX.SheetFrameOverwriteDimStyleModes.sfodsmBackgroundColorByStyle

         End Select
     End With

 End Sub