|
DigiPara Liftdesigner LDX API
|
API method: ILDXVisualScene5.VS_MODE
Treename: Sheets.LdvSheet1.LdvFrame2.Scene.
' from Samples/Src/LDXAPIExamples/Example_LDXSheetFrame.vb
<APIHelpAttribute(APIHelpModes.FireCalcModel Or APIHelpModes.LoadLD3File, {APIHelpModes.InputParaLDXDoc}, "Sheets.LdvSheet1.LdvFrame2.Scene.", "LDXVisualScene~VS_MODE", "Change rendering mode")>
Public Shared Sub RenderMode(ByRef ldxDocument As DigiPara.LDX.LDXDocument)
If ldxDocument.GetObject("Sheets.LdvSheet1.LdvFrame2.") Is Nothing Then
MsgBox("Desired sheet frame not found! Please reload the relevant .ld3 file.")
Exit Sub
End If
With DirectCast(ldxDocument.GetLDXObject("Sheets.LdvSheet1.LdvFrame2.").LDXType, DigiPara.LDX.LDXSheetFrame)
With .LocalVisualScene
' activate individual settings for this frame for the rendering mode and resolution
' without it, the render mode is influenced by the parent sheet .VisualScene and if that does not set individual settings,
' .VisualScene on the parent LDXSheets.
.BY_OWNER_MODE = .BY_OWNER_MODE And Not DigiPara.LDX.VisualSceneByOwnerModes.vsbomFrameRenderMode And Not DigiPara.LDX.VisualSceneByOwnerModes.vsbomFrameRenderResolution
' cycle between modes
Dim currentMode As DigiPara.LDX.VisualSceneModes = .VS_MODE And DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeMask
If currentMode = DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeLineOnly Then
' plain rendering, no lines
.VS_MODE = .VS_MODE And Not DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeMask Or DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeColored
' very low resolution
.RenderedImageMaxHeight = 128
.RenderedImageMaxWidth = 128
ElseIf currentMode = DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeColored Then
' mixed/hybrid mode: lines and rendered background
.VS_MODE = .VS_MODE And Not DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeMask Or DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeMixed
' high resolution
.RenderedImageMaxHeight = 2048
.RenderedImageMaxWidth = 2048
Else
' back to line mode
.VS_MODE = .VS_MODE And Not DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeMask Or DigiPara.LDX.VisualSceneModes.vsmFrameRenderModeLineOnly
End If
End With
End With
End Sub